Generate GCODE

lib/Slic3r.pm

@@ -16,6 +16,16 @@ use Slic3r::Surface;
 our $layer_height       = 0.4;
 our $resolution         = 0.1;
 our $perimeter_offsets  = 3;
-our $flow_width         = 0.4;  # make sure this is > $resolution
+our $flow_width         = 0.4;  # TODO: verify this is a multiple of $resolution
+our $temperature        = 195;
+
+our $flow_rate          = 60;   # mm/sec
+our $print_feed_rate    = 60;   # mm/sec
+our $travel_feed_rate   = 80;   # mm/sec
+our $bottom_layer_speed_ratio = 0.6;
+
+our $use_relative_e_distances = 1;
+
+our $print_center       = [100,100];  # object will be centered around this point
 
 1;

lib/Slic3r/Line.pm

@@ -1,9 +1,11 @@
 package Slic3r::Line;
 use Moose;
-
 use Moose::Util::TypeConstraints;
 use Scalar::Util qw(weaken);
 
+subtype 'Slic3r::Line::Length', as 'Int';
+coerce 'Slic3r::Line::Length', from 'Num', via { sprintf '%.0f', $_ };
+
 has 'a' => (
     is          => 'ro',
     isa         => 'Slic3r::Point',

lib/Slic3r/Point.pm

@@ -40,4 +40,11 @@ sub coincides_with {
     return $self->x == $point->x && $self->y == $point->y; #=
 }
 
+sub distance_to {
+    my $self = shift;
+    my ($point) = @_;
+    
+    return sqrt(($point->x - $self->x)**2 + ($point->y - $self->y)**2); #-
+}
+
 1;

lib/Slic3r/Print.pm

@@ -1,6 +1,23 @@
 package Slic3r::Print;
 use Moose;
 
+use constant X => 0;
+use constant Y => 1;
+
+has 'x_length' => (
+    is          => 'ro',
+    isa         => 'Slic3r::Line::Length',
+    required    => 1,
+    coerce      => 1,
+);
+
+has 'y_length' => (
+    is          => 'ro',
+    isa         => 'Slic3r::Line::Length',
+    required    => 1,
+    coerce      => 1,
+);
+
 has 'layers' => (
     traits  => ['Array'],
     is      => 'rw',
@@ -38,4 +55,96 @@ sub extrude_perimeters {
     }
 }
 
+sub export_gcode {
+    my $self = shift;
+    my ($file) = @_;
+    
+    # calculate speed for gcode commands
+    my $travel_feed_rate      = $Slic3r::travel_feed_rate * 60;  # mm/min
+    my $print_feed_rate       = $Slic3r::print_feed_rate  * 60;  # mm/min
+    my $extrusion_speed_ratio = ($Slic3r::flow_rate / $Slic3r::print_feed_rate);
+    
+    # calculate number of decimals
+    my $dec = length((1 / $Slic3r::resolution) - 1);
+    
+    # calculate X,Y shift to center print around specified origin
+    my @shift = (
+        $Slic3r::print_center->[X] - ($self->x_length * $Slic3r::resolution / 2),
+        $Slic3r::print_center->[Y] - ($self->y_length * $Slic3r::resolution / 2),
+    );
+    
+    # open output gcode file
+    open my $fh, ">", $file
+        or die "Failed to open $file for writing\n";
+    
+    # write start commands to file
+    # TODO: this must be customizable by user
+    print  $fh "G28 ; home all axes\n";
+    printf $fh "M109 S%d ; wait for temperature to be reached\n", $Slic3r::temperature;
+    print  $fh "G90 ; use absolute coordinates\n";
+    print  $fh "G21 ; set units to millimeters\n";
+    if ($Slic3r::use_relative_e_distances) {
+        print $fh "M83 ; use relative distances for extrusion\n";
+    } else {
+        print $fh "M82 ; use absolute distances for extrusion\n";
+    }
+    
+    # make up a subroutine to generate G1 commands
+    my $G1 = sub {
+        my ($point, $z, $extrusion_distance, $comment) = @_;
+        printf $fh "G1 X%.${dec}f Y%.${dec}f Z%.${dec}f", 
+            ($point->x * $Slic3r::resolution) + $shift[X], 
+            ($point->y * $Slic3r::resolution) + $shift[Y], #**
+            $z;
+        if ($extrusion_distance) {
+            printf $fh " F%.${dec}f E%.${dec}f", 
+                $print_feed_rate, 
+                ($extrusion_distance * $extrusion_speed_ratio * $Slic3r::resolution);
+        } else {
+            printf $fh " F%.${dec}f", $travel_feed_rate;
+        }
+        printf $fh " ; %s", $comment if $comment;
+        print  $fh "\n";
+    };
+    
+    # write gcode commands layer by layer
+    foreach my $layer (@{ $self->layers }) {
+        my $z = ($layer->z * $Slic3r::resolution);
+        
+        # go to layer
+        # TODO: retraction
+        printf $fh "G1 Z%.${dec}f F%.${dec}f ; move to next layer\n", 
+            $z, $travel_feed_rate;
+        
+        # extrude perimeters
+        foreach my $perimeter (@{ $layer->perimeters }) {
+            
+            # reset extrusion distance counter
+            my $extrusion_distance = 0;
+            if (!$Slic3r::use_relative_e_distances) {
+                print $fh "G92 E0 ; reset extrusion distance\n";
+            }
+            
+            # go to first point (without extruding)
+            $G1->($perimeter->lines->[0]->a, $z, 0, 'move to first perimeter point');
+            
+            # extrude while going to next points
+            foreach my $line (@{ $perimeter->lines }) {
+                $extrusion_distance = 0 if $Slic3r::use_relative_e_distances;
+                $extrusion_distance += $line->a->distance_to($line->b);
+                $G1->($line->b, $z, $extrusion_distance, 'perimeter');
+            }
+        }
+    }
+    
+    # write end commands to file
+    # TODO: this must be customizable by user
+    print $fh "M104 S0 ; turn off temperature\n";
+    print $fh "G28 X0 ; home X axis\n";
+    print $fh "M84 ; disable motors\n";
+    
+    # close our gcode file
+    close $fh;
+}
+
 1;

lib/Slic3r/STL.pm

@@ -14,8 +14,7 @@ sub parse_file {
     my $self = shift;
     my ($file) = @_;
     
-    my $print = Slic3r::Print->new;
+    # open STL file
-    
     my $stl = CAD::Format::STL->new->load($file);
     
     # we only want to work with positive coordinates, so let's 
@@ -31,6 +30,12 @@ sub parse_file {
         }
     }
     
+    # initialize print job
+    my $print = Slic3r::Print->new(
+        x_length => ($extents[X][MAX] - $extents[X][MIN]) / $Slic3r::resolution,
+        y_length => ($extents[Y][MAX] - $extents[Y][MIN]) / $Slic3r::resolution,
+    );
+    
     # calculate the displacements needed to 
     # have lowest value for each axis at coordinate 0
     my @shift = map 0 - $extents[$_][MIN], X,Y,Z;

slic3r.pl

@@ -16,6 +16,8 @@ my $print = $stl_parser->parse_file("testcube20mm.stl");
 
 $print->extrude_perimeters;
 
+$print->export_gcode("testcube20mm.gcode");
+
 #XXX $print;
 
 __END__