79 lines
2.5 KiB
Perl
79 lines
2.5 KiB
Perl
package Slic3r::Layer;
|
|
use Moo;
|
|
|
|
use Slic3r::Geometry::Clipper qw(union_ex);
|
|
|
|
has 'id' => (is => 'rw', required => 1); # sequential number of layer, 0-based
|
|
has 'object' => (is => 'ro', weak_ref => 1, required => 1);
|
|
has 'regions' => (is => 'ro', default => sub { [] });
|
|
has 'slicing_errors' => (is => 'rw');
|
|
|
|
has 'slice_z' => (is => 'lazy');
|
|
has 'print_z' => (is => 'lazy');
|
|
has 'height' => (is => 'lazy');
|
|
has 'flow' => (is => 'ro', default => sub { $Slic3r::flow });
|
|
|
|
# collection of expolygons generated by slicing the original geometry;
|
|
# also known as 'islands' (all regions are merged here)
|
|
has 'slices' => (is => 'rw');
|
|
|
|
# ordered collection of extrusion paths to fill surfaces for support material
|
|
has 'support_fills' => (is => 'rw');
|
|
|
|
# Z used for slicing
|
|
sub _build_slice_z {
|
|
my $self = shift;
|
|
|
|
if ($self->id == 0) {
|
|
return $Slic3r::Config->get_value('first_layer_height') / 2 / &Slic3r::SCALING_FACTOR;
|
|
}
|
|
return ($Slic3r::Config->get_value('first_layer_height') + (($self->id-1) * $Slic3r::Config->layer_height) + ($Slic3r::Config->layer_height/2))
|
|
/ &Slic3r::SCALING_FACTOR; #/
|
|
}
|
|
|
|
# Z used for printing
|
|
sub _build_print_z {
|
|
my $self = shift;
|
|
return ($Slic3r::Config->get_value('first_layer_height') + ($self->id * $Slic3r::Config->layer_height)) / &Slic3r::SCALING_FACTOR;
|
|
}
|
|
|
|
sub _build_height {
|
|
my $self = shift;
|
|
return $self->id == 0 ? $Slic3r::Config->get_value('first_layer_height') : $Slic3r::Config->layer_height;
|
|
}
|
|
|
|
sub region {
|
|
my $self = shift;
|
|
my ($region_id) = @_;
|
|
|
|
if (!defined $self->regions->[$region_id]) {
|
|
$self->regions->[$region_id] = Slic3r::Layer::Region->new(
|
|
layer => $self,
|
|
region => $self->object->print->regions->[$region_id],
|
|
);
|
|
}
|
|
return $self->regions->[$region_id];
|
|
}
|
|
|
|
# merge all regions' slices to get islands
|
|
sub make_slices {
|
|
my $self = shift;
|
|
|
|
# optimization for single-region layers
|
|
my @regions_with_slices = grep { @{$_->slices} } @{$self->regions};
|
|
if (@regions_with_slices == 1) {
|
|
$self->slices([ map $_->expolygon, @{$regions_with_slices[0]->slices} ]);
|
|
return;
|
|
}
|
|
|
|
$self->slices(union_ex([ map $_->p, map @{$_->slices}, @{$self->regions} ]));
|
|
}
|
|
|
|
sub make_perimeters {
|
|
my $self = shift;
|
|
Slic3r::debugf "Making perimeters for layer %d\n", $self->id;
|
|
$_->make_perimeters for @{$self->regions};
|
|
}
|
|
|
|
1;
|