934e277ccd
Breaking Changes: * `0 < label-NAME-maxlen < 3` will now throw an exception and disable the containing module, if ellipsis is enabled for that label. (#1198) Changelog: Deprecations: * `internal/volume` is now called `internal/alsa` (#967) * temperature: The `%temperature%` is deprecated in favor of `%temperature-c%`(#897) * mpd: `icon-repeatone` is deprecated in favor of `icon-single` (#1295), see #1279 Features: * feat(mpd): Add support for icon-consume (#861) * feat(bspwm): Add workspace separator (#942) * feat(i3): Add workspace separator (#938), see #929 * feat(build): Make polybar build on FreeBSD (#931, jaagr/xpp#8), see #239 * feat(volume): Add pulseaudio backend (#779) * feat(script): Add %pid% token for tail commands (#934) * feat(temp): Add temperature tokens without unit (#897) * feat(memory): Add memory used/free ramp (#1038), see #1037 * feat(memory): Add swap tokens (#1018) * feat(net): Add unknown-as-up option (#1077), see #457 * feat(config): Support fractional size and offset (#972), see #953 * feat(xwindow): Add label-empty (#1136) * feat(battery): Add animation-discharging (analog to animation-charging) (#1190) * feat(config): Support pixel offset for bar size and offset values (#1224) * feat(mpd): Add `%album-artist%` token (#1263) * feat(net): Add local_ip6 token (#1239), see #1234 * feat(net): Add nl80211 support (#1009), see #277 Fixes: * fix(mpd): Wrong elapsed time when after standby (#921), see #915 * fix(config): Wrong min, maxlen when using the same token multiple times (#974), see #971 * fix(battery): use power_now correctly (#958), see #928 * fix(mpd): Crash when mpd isn't running (#983), see #979 * fix(xworkspaces): Respect 'enable-scroll' (#1002) * fix(xbacklight): Respect 'enable-scroll' (#1014) * fix(build): support xcb-proto >=1.13 (jaagr/xpp#11), see #973 * fix(mpd): Respect MPD_HOST env variable (#1025), see #1007 * fix(i3): Reconnect i3 IPC socket on restart/error (#1099), see #762 * fix(cursor): Occasional crash on mouseover (#1124), see #1117 * fix(net): Mark 'not connected' on querying failure (#1171), see #1163 * fix(gcc): Fix -Wstringop-truncation warning (#1216, jaagr/i3ipcpp#7), see #1215 * fix(builder): Don't truncate colors with same channels (#1217), see #1183 * fix(bspwm): Consistent behavior when scrolling through multiple desktops (#986), see #981 * fix(builder): Respect label-ellipsis option (#1198), see #1194
47 lines
1.5 KiB
Bash
47 lines
1.5 KiB
Bash
# Maintainer: Michael Carlberg <c@rlberg.se>
|
|
# Contributor: Michael Carlberg <c@rlberg.se>
|
|
_pkgname=polybar
|
|
pkgname="${_pkgname}-git"
|
|
pkgver=3.2.0
|
|
pkgrel=1
|
|
pkgdesc="A fast and easy-to-use status bar"
|
|
arch=("i686" "x86_64")
|
|
url="https://github.com/jaagr/polybar"
|
|
license=("MIT")
|
|
depends=("cairo" "xcb-util-image" "xcb-util-wm" "xcb-util-xrm" "xcb-util-cursor")
|
|
optdepends=("alsa-lib: alsa module support"
|
|
"pulseaudio: pulseaudio module support"
|
|
"libmpdclient: mpd module support"
|
|
"libnl: network module support"
|
|
"wireless_tools: network module support (legacy)"
|
|
"jsoncpp: i3 module support"
|
|
"i3-wm: i3 module support"
|
|
"ttf-unifont: Font used in example config"
|
|
"siji-git: Font used in example config"
|
|
"curl: github module support")
|
|
makedepends=("cmake" "git" "python" "python2" "pkg-config")
|
|
provides=("polybar")
|
|
conflicts=("polybar")
|
|
install="${_pkgname}.install"
|
|
source=("${_pkgname}::git+${url}.git")
|
|
md5sums=("SKIP")
|
|
|
|
pkgver() {
|
|
git -C "${_pkgname}" describe --long --tags | sed "s/-/.r/;s/-/./g"
|
|
}
|
|
|
|
prepare() {
|
|
git -C "${_pkgname}" submodule update --init --recursive
|
|
mkdir -p "${_pkgname}/build"
|
|
}
|
|
|
|
build() {
|
|
cd "${_pkgname}/build" || exit 1
|
|
cmake -DCMAKE_INSTALL_PREFIX=/usr ..
|
|
cmake --build .
|
|
}
|
|
|
|
package() {
|
|
cmake --build "${_pkgname}/build" --target install -- DESTDIR="${pkgdir}"
|
|
install -Dm644 "${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
|
|
}
|